mirror of
https://github.com/solemnwarning/ipxwrapper
synced 2024-12-30 16:45:37 +01:00
5ff0855485
Dump most of the old "unit" tests which were more system tests and only tested a small amount of functionality against the host. The new test suite is a lot more thorough and tests an arbitrary Windows version over the network rather than testing within the host's WinSock environment. More documentation detailing how to run this will follow.
134 lines
2.8 KiB
Perl
134 lines
2.8 KiB
Perl
# IPXWrapper test suite
|
|
# Copyright (C) 2014 Daniel Collins <solemnwarning@solemnwarning.net>
|
|
#
|
|
# This program is free software; you can redistribute it and/or modify it
|
|
# under the terms of the GNU General Public License version 2 as published by
|
|
# the Free Software Foundation.
|
|
#
|
|
# This program is distributed in the hope that it will be useful, but WITHOUT
|
|
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
|
|
# FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
|
|
# more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License along with
|
|
# this program; if not, write to the Free Software Foundation, Inc., 51
|
|
# Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
|
|
|
|
use strict;
|
|
use warnings;
|
|
|
|
package IPXWrapper::Tool::IPXRecv;
|
|
|
|
use Carp;
|
|
use IPC::Open3;
|
|
use POSIX qw(:signal_h);
|
|
use Test::Spec;
|
|
|
|
sub new
|
|
{
|
|
my ($class, $host_ip, @exe_args) = @_;
|
|
|
|
my @command = ("ssh", $host_ip, "Z:\\tools\\ipx-recv.exe", @exe_args);
|
|
|
|
note(join(" ", @command));
|
|
|
|
# No need for error checking here - open3 throws on failure.
|
|
my $pid = open3(my $in, my $out, undef, @command);
|
|
|
|
my $self = bless({
|
|
pid => $pid,
|
|
out => $out,
|
|
|
|
sockets => {},
|
|
}, $class);
|
|
|
|
my $output = "";
|
|
|
|
while(defined(my $line = <$out>))
|
|
{
|
|
$output .= $line;
|
|
|
|
$line =~ s/[\r\n]//g;
|
|
|
|
if($line =~ m{^Bound socket (\d+) to local address: (.+)/(.+)/(.+)$})
|
|
{
|
|
$self->{sockets}->{$1} = {
|
|
net => $2,
|
|
node => $3,
|
|
sock => $4,
|
|
};
|
|
}
|
|
elsif($line eq "Ready")
|
|
{
|
|
return $self;
|
|
}
|
|
}
|
|
|
|
die("Didn't get expected output from ipx-recv.exe:\n$output");
|
|
}
|
|
|
|
sub DESTROY
|
|
{
|
|
my ($self) = @_;
|
|
|
|
if(defined($self->{pid}))
|
|
{
|
|
kill(SIGKILL, $self->{pid});
|
|
waitpid($self->{pid}, 0);
|
|
}
|
|
}
|
|
|
|
sub kill_and_read
|
|
{
|
|
my ($self) = @_;
|
|
|
|
unless(defined($self->{pid}))
|
|
{
|
|
confess("kill_and_read called multiple times");
|
|
}
|
|
|
|
# Kill the child process so we can read EOF from the pipe once we have
|
|
# all the output.
|
|
|
|
kill(SIGKILL, $self->{pid});
|
|
waitpid($self->{pid}, 0);
|
|
delete $self->{pid};
|
|
|
|
my $out = $self->{out};
|
|
my @packets = ();
|
|
|
|
while(defined(my $line = <$out>))
|
|
{
|
|
$line =~ s/[\r\n]//g;
|
|
|
|
if($line =~ m{^Received (\d+) bytes \((.*)\) on socket (\d+) from (.+)/(.+)/(.+)$})
|
|
{
|
|
die("Received packet on unknown socket $3")
|
|
unless(defined($self->{sockets}->{$3}));
|
|
|
|
die("Read a packet with the wrong size, binary data used in test?")
|
|
unless($1 == length($2));
|
|
|
|
push(@packets, {
|
|
sock => $3,
|
|
data => $2,
|
|
|
|
local_net => $self->{sockets}->{$3}->{net},
|
|
local_node => $self->{sockets}->{$3}->{node},
|
|
local_sock => $self->{sockets}->{$3}->{sock},
|
|
|
|
src_network => $4,
|
|
src_node => $5,
|
|
src_socket => $6,
|
|
});
|
|
}
|
|
else{
|
|
die("Malformed line read from ipx-recv.exe: $line");
|
|
}
|
|
}
|
|
|
|
return @packets;
|
|
}
|
|
|
|
1;
|